Programmi Visual Basic - prof.Claudio Maccherani

Programmi Visual Basic - prof. Claudio Maccherani - Perugia - 2009
accesso a database (Access) in Visual Basic 6.0 con ADO (ActiveX Data Object) e Data Control

applicazione Alunni5 - database MS Access Alunni.mdb - tabella Alunni
Tabella ALUNNI:
Matricola long, Nome string_*30, Data Nascita date, Luogo Nascita string_*20,
Classe integer, Sezione string_*1, Corso string_*1
datAlunni	( impostato da codice			txtMatricola	DataSource	datAlunni
[Adodc]	al Form_Load )				DataField	Matricola
				txtNome	DataSource	datAlunni
grdAlunni	DataSource	datAlunni	[DataGrid]		DataField	Nome

 '+------------------------------------------------------------------------------------+
 '| ALUNNI5 - applicazione esempio di gestione singola tabella                         |
 '|           utilizzando controllo ADO Data (Microsoft ADO Data Control 6.0) e        |
 '|           griglia DataGrid (Microsoft Data Grid Control 6.0 (SP5))                 |
 '|           [Prof. Claudio Maccherani]                                               |
 '+------------------------------------------------------------------------------------+
 Option Explicit ' per controllare la dichiarazione delle variabili
 Dim Segnalibro As Variant  ' segnalibro per marcare il record corrente
 Dim Matricola As Long      ' per la ricerca
 Dim Nome As String         ' per la ricerca
 Dim Classe As Integer      ' per la ricerca
 Dim FlagRic As Boolean     ' flag per il controllo errore di Validate in caso di ricerca
 Dim boAnnulla As Boolean   ' per annullare "Nuovo" alunno
 Dim stConnection As String ' stringa di connessione al database
 '--------------------------------------------------------------------------------------
 Private Sub Form_Load()   ' viene eseguito al momento del caricamento in memoria del form
   ' al caricamento si possono impostare le proprietà dei controlli
   ' la proprietà Path dell'oggetto App restituisce  il percorso dell'applicazione
   ' impostazione della stringa di connessione a database Access 2000
   stConnection = "Provider=Microsoft.Jet.OLEDB.4.0;Persist Security Info=False;
                   Data Source=" & App.Path & "\alunni2000.mdb" ' per Access 2000
   stConnection = "Provider=Microsoft.Jet.OLEDB.3.51;
                   Data Source=" & App.Path & "\Alunni.mdb"     ' per Access 97
   With datAlunni ' inizializzazione proprietà del controllo ADO Data
      .ConnectionString = stConnection ' stringa di connessione al database provider dei dati
      .CursorType = adOpenKeyset       ' cursore direzionale
      .LockType = adLockOptimistic     ' blocco ottimistico, record per record
      .RecordSource = "Alunni"         ' recordset, tabella o query (qui tabella "Alunni")
      .Refresh                         ' crea il recordset associato
   End With
   ' Imposta le dimensioni del form e lo centra
   Me.Left = (Screen.Width - Me.Width) / 2: Me.Top = (Screen.Height - Me.Height) / 2
   Me.Move (Screen.Width - Width) / 2, (Screen.Height - Height) / 2
   boAnnulla = False
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub Form_Activate() ' eseguito quando il form diventa attivo, dopo il caricamento
   selIndexMatricola = True ' imposta il pulsante dell'indice matricola (indice primario)
   FlagRic = False          ' imposta il flag della ricerca
   Call Imposta_Griglia     ' imposta le dimensioni della griglia
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub Imposta_Griglia() ' imposta le dimensioni delle colonne della griglia
   With grdAlunni ' inizializzazione Data Grid
      .Columns(0).Width = 800
      .Columns(2).Width = 1000
      .Columns(3).Width = 1600
      .AllowRowSizing = False
      .Refresh
   End With
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdFirst_Click() ' pulsante FIRST
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      datAlunni.Recordset.MoveFirst ' va al primo record (dell'indice corrente)
   End If
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdNext_Click() ' pulsante NEXT
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      datAlunni.Recordset.MoveNext    ' va al prossimo record (dell'indice corrente)
      If datAlunni.Recordset.EOF Then ' controlla se si è "usciti" dalla tabella
         datAlunni.Recordset.MoveLast ' e se si torna sull'ultimo record
      End If
   End If
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdPrevious_Click() ' pulsante PREV
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      datAlunni.Recordset.MovePrevious ' va al precedente record (dell'indice corrente)
      If datAlunni.Recordset.BOF Then  ' controlla se si è "usciti" dalla tabella
         datAlunni.Recordset.MoveFirst ' e se si torna sul primo record
      End If
   End If
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdLast_Click() ' pulsante LAST
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      datAlunni.Recordset.MoveLast ' va al primo record (dell'indice corrente)
   End If
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdNuovo_Click()  ' pulsante NUOVO
   datAlunni.Recordset.AddNew ' aggiunge un record vuoto
   MsgBox "Inserisci i dati e memorizza lo studente con il pulsante SALVA"
   txtMatricola.SetFocus      ' posiziona il cursore sulla matricola
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdAnnulla_Click() ' pulsante annulla
   boAnnulla = True            ' annulla l'ADDNEW del pulsante NUOVO
   datAlunni.Recordset.MoveLast
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdSalva_Click()  ' pulsante SALVA
   If datAlunni.Recordset.BOF And datAlunni.Recordset.EOF Then
      Exit Sub ' se tabella vuota (prima non si è fatto neppure l'AddNew), esce
   End If
   On Error GoTo Errore_Salva ' attiva la gestione dell'errore
   datAlunni.Recordset.Update ' memorizza le variazioni del record corrente
   MsgBox "Studente registrato / variato"
   On Error GoTo 0 ' disabilita la gestione dell'errore
   datAlunni.Refresh
   Call Imposta_Griglia
   Exit Sub
 Errore_Salva: ' gestione dell'errore
   ' l'errore numero 3020 è atteso e il programma NON deve segnalarlo
   If Err.Number <> 3020 Then
      ' in err.number c'è il codice dell'errore e in err.description la sua descrizione
      MsgBox "Errore " & Err.Number & " " & Err.Description
   End If
   ' riprende l'esecuzione dall'istruzione seguente quella che ha provocato l'errore
   Resume Next
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdCanc_Click() ' pulsante CANC
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      If MsgBox("Confermi la cancellazione dello studente corrente ?", vbYesNo) = vbYes Then
         ' dopo aver controllato che la tabella non sia vuota ..
         datAlunni.Recordset.Delete ' cancella il record corrente
         cmdNext_Click              ' si posiziona sul record successivo
      End If
   End If
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdFine_Click() ' pulsante FINE
   End ' chiusura programma
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub datAlunni_Validate(Action As Integer, Save As Integer)
   ' l'evento Validate si verifica subito prima che un record diventi corrente (Move)
   ' o con AddNew, Delete, Update. Qui si possono fare dei controlli e, se non va bene,
   ' si può annullare l'operazione
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      If boAnnulla Then ' annulla "nuovo" alunno
         Save = 0: boAnnulla = False: Exit Sub
      End If
      If Not FlagRic Then
      ' se il validate NON è stato attivato dalla SEEK della ricerca esegue i controlli
         If Len(txtMatricola) = 0 Then ' controllo esistenza matricola
            MsgBox "Manca la Matricola !" ' segnala l'errore
            Action = 0   ' annulla l'azione che ha causato il Validate
            Save = False ' annulla la memorizzazione di eventuali variazioni
            txtMatricola.SetFocus ' posiziona il cursore sulla matricola
         End If
         If Val(txtClasse) < 1 Or Val(txtClasse) > 5 Then ' controllo correttezza classe
            MsgBox "Classe errata !" ' segnala l'errore
            Action = 0   ' annulla l'azione che ha causato il Validate
            Save = False ' annulla la memorizzazione di eventuali variazioni
            txtClasse.SetFocus ' posiziona il cursore sulla matricola
         End If
      End If
   End If
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub selIndexMatricola_Click() ' pulsante di opzione MATRICOLA
   datAlunni.RecordSource = "Select * From Alunni Order By Matricola" 'indice Matricola
   datAlunni.Refresh ' ricrea il recordset
   cmdFirst_Click    ' si posiziona sul primo record (dell'indice attivato)
   Call Imposta_Griglia
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub selIndexNome_Click() ' pulsante di opzione NOME
   datAlunni.RecordSource = "Select * From Alunni Order By Nome" ' indice Nome
   datAlunni.Refresh ' ricrea il recordset
   cmdFirst_Click    ' si posiziona sul primo record (dell'indice attivato)
   Call Imposta_Griglia
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub selIndexClasse_Click()  ' pulsante di opzione CLASSE
   datAlunni.RecordSource = "Select * From Alunni Order By Classe" ' indice Classe
   datAlunni.Refresh ' ricrea il recordset
   cmdFirst_Click    ' si posiziona sul primo record (dell'indice attivato)
   Call Imposta_Griglia
 End Sub
 '--------------------------------------------------------------------------------------
 Private Sub cmdRicerca_Click() ' pulsante RICERCA
   Dim stCriterio As String: stCriterio = ""
   If datAlunni.Recordset.BOF And datAlunni.Recordset.EOF Then
      Exit Sub ' se la tabella è vuota, esce
   End If
   Segnalibro = datAlunni.Recordset.Bookmark ' imposta il segnalibro su record corrente
   If selIndexMatricola Then ' se l'indice corrente è Matricola
      Matricola = InputBox("Matricola da cercare (>=)")
      stCriterio = "Matricola >= " & CStr(Matricola)
   ElseIf selIndexNome Then ' se l'indice corrente è Nome
      Nome = InputBox("Nome da cercare (>=)")
      stCriterio = "Nome >= '" & Nome & "'"
   ElseIf selIndexClasse Then ' se l'indice corrente è Classe
      Classe = InputBox("Classe da cercare (>=)")
      stCriterio = "Classe >= " & CStr(Classe)
   End If
   If Len(Trim(stCriterio)) > 0 Then ' impostata una selezione
       FlagRic = True ' imposta il flag per i controlli del validate
       datAlunni.Recordset.Find (stCriterio) ' esegue la ricerca
       ' se non esiste, si riposiziona sul record precedente
       If datAlunni.Recordset.EOF Then datAlunni.Recordset.Bookmark = Segnalibro
       FlagRic = False ' reimposta il flag per i controlli del validate
   End If
 End Sub
 '--------------------------------------------------------------------------------------