Programmi Visual Basic - prof.Claudio Maccherani

Programmi Visual Basic - prof. Claudio Maccherani - Perugia - 2009
accesso a database (Access) in Visual Basic 6.0 con Data Control e Data Grid ADO (ActiveX Data Object)

applicazione Alunni3 - database MS Access Alunni.mdb - tabella Alunni
Tabella ALUNNI:
Matricola long, Nome string_*30, Data Nascita date, Luogo Nascita string_*20,
Classe integer, Sezione string_*1, Corso string_*1

 '+------------------------------------------------------------------------------------------+
 '| ALUNNI3 - applicazione VB6, esempio di gestione singola tabella                          |
 '|           utilizzando Data Control ADO e DataGrid connessa (ActiveX Data Object)         |
 '|          (Prof.Claudio Maccherani)                                                       |
 '+------------------------------------------------------------------------------------------+
 Option Explicit ' per controllare la dichiarazione delle variabili
 Dim Matricola As Long      ' per la ricerca
 Dim Nome As String         ' per la ricerca
 Dim Classe As Integer      ' per la ricerca
 Dim FlagRic As Boolean     ' flag per il controllo errore di Validate in caso di ricerca
 Dim stConnection As String    ' stringa di connessione
 Dim stSql As String           ' stringa comando Sql
 Dim cnAlu As New ADODB.Connection ' connessione alunni
 Dim rsAlu As New ADODB.Recordset  ' recordset alunni
 '--------------------------------------------------------------------------------------------
 Private Sub Form_Load()   ' viene eseguito al momento del caricamento in memoria del form
   ' al caricamento si possono impostare le proprietà dei controlli
   ' la proprietà Path dell'oggetto App restituisce  il percorso dell'applicazione
   stConnection = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & App.Path & "\Alunni.mdb"
   With datAlunni ' inizializzazione proprietà del controllo ADO Data
      .ConnectionString = stConnection ' stringa di connessione al database provider dei dati
      .CursorType = adOpenKeyset       ' cursore direzionale
      .LockType = adLockOptimistic     ' blocco ottimistico, record per record
      .RecordSource = "Alunni"         ' recordset, tabella o query (qui tabella "Alunni")
      .Refresh                         ' crea il recordset associato
   End With
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub Form_Activate()' eseguito quando il form diventa attivo, dopo il caricamento
   selIndexMatricola = True ' imposta il pulsante dell'indice matricola (indice primario)
   Call cmdFirst_Click      ' legge il primo
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub Imposta_Griglia() ' imposta le dimensioni delle colonne della griglia
   With grdAlunni ' inizializzazione Data Grid
      .Columns(0).Width = 800
      .Columns(2).Width = 1000
      .Columns(3).Width = 1600
      .AllowRowSizing = False
      .Refresh
   End With
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub cmdFirst_Click() ' pulsante FIRST
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      datAlunni.Recordset.MoveFirst ' va al primo record (dell'indice corrente)
   End If
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub cmdNext_Click() ' pulsante NEXT
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      datAlunni.Recordset.MoveNext    ' va al prossimo record (dell'indice corrente)
      If datAlunni.Recordset.EOF Then ' controlla se si è "usciti" dalla tabella
         datAlunni.Recordset.MoveLast ' e se si torna sull'ultimo record
      End If
   End If
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub cmdPrevious_Click() ' pulsante PREV
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      datAlunni.Recordset.MovePrevious ' va al precedente record (dell'indice corrente)
      If datAlunni.Recordset.BOF Then  ' controlla se si è "usciti" dalla tabella
         datAlunni.Recordset.MoveFirst ' e se si torna sul primo record
      End If
   End If
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub cmdLast_Click() ' pulsante LAST
   If Not datAlunni.Recordset.BOF And Not datAlunni.Recordset.EOF Then
      ' dopo aver controllato che la tabella non sia vuota ..
      datAlunni.Recordset.MoveLast ' va al primo record (dell'indice corrente)
   End If
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub selIndexMatricola_Click() ' pulsante di opzione MATRICOLA
   datAlunni.RecordSource = "Select * From Alunni Order By Matricola" 'indice Matricola
   datAlunni.Refresh ' ricrea il recordset
   cmdFirst_Click    ' si posiziona sul primo record (dell'indice attivato)
   Call Imposta_Griglia
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub selIndexNome_Click() ' pulsante di opzione NOME
   datAlunni.RecordSource = "Select * From Alunni Order By Nome" ' indice Nome
   datAlunni.Refresh ' ricrea il recordset
   cmdFirst_Click    ' si posiziona sul primo record (dell'indice attivato)
   Call Imposta_Griglia
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub selIndexClasse_Click()  ' pulsante di opzione CLASSE
   datAlunni.RecordSource = "Select * From Alunni Order By Classe" ' indice Classe
   datAlunni.Refresh ' ricrea il recordset
   cmdFirst_Click    ' si posiziona sul primo record (dell'indice attivato)
   Call Imposta_Griglia
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub Visualizza_Record() ' visualizzazione record corrente
   txtMatricola = rsAlu![Matricola]: txtNome = rsAlu![Nome]
   txtData = rsAlu![Data Nascita]: txtLuogo = rsAlu![Luogo Nascita]
   txtClasse = rsAlu![Classe]: txtSezione = rsAlu![Sezione]: txtCorso = rsAlu![Corso]
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub cmdCanc_Click() ' pulsante CANC - cancellazine record
  With datAlunni.Recordset
    .Delete
    .MoveNext
    If .EOF Then .MoveLast
  End With
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub cmdNuovo_Click() ' pulsante NUOVO - inserimento nuovo record
  datAlunni.Recordset.MoveLast
  grdAlunni.SetFocus
  SendKeys "{down}"
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub cmdSalva_Click() ' pulsante SALVA - salvataggio record e aggiornamento
   datAlunni.Recordset.UpdateBatch adAffectAll 
 End Sub
 '--------------------------------------------------------------------------------------------
 Private Sub cmdFine_Click() ' pulsante FINE
   End ' chiusura programma
 End Sub
 '--------------------------------------------------------------------------------------------